home *** CD-ROM | disk | FTP | other *** search
/ Languguage OS 2 / Languguage OS II Version 10-94 (Knowledge Media)(1994).ISO / gnu / smaltalk.lha / smalltalk-1.1.1 / Character.st < prev    next >
Text File  |  1991-09-12  |  5KB  |  232 lines
  1. "======================================================================
  2. |
  3. |   Character Method Definitions
  4. |
  5.  ======================================================================"
  6.  
  7.  
  8. "======================================================================
  9. |
  10. | Copyright (C) 1990, 1991 Free Software Foundation, Inc.
  11. | Written by Steve Byrne.
  12. |
  13. | This file is part of GNU Smalltalk.
  14. |
  15. | GNU Smalltalk is free software; you can redistribute it and/or modify it
  16. | under the terms of the GNU General Public License as published by the Free
  17. | Software Foundation; either version 1, or (at your option) any later version.
  18. | 
  19. | GNU Smalltalk is distributed in the hope that it will be useful, but WITHOUT
  20. | ANY WARRANTY; without even the implied warranty of MERCHANTABILITY or FITNESS
  21. | FOR A PARTICULAR PURPOSE.  See the GNU General Public License for more
  22. | details.
  23. | 
  24. | You should have received a copy of the GNU General Public License along with
  25. | GNU Smalltalk; see the file COPYING.  If not, write to the Free Software
  26. | Foundation, 675 Mass Ave, Cambridge, MA 02139, USA.  
  27. |
  28.  ======================================================================"
  29.  
  30.  
  31. "
  32. |     Change Log
  33. | ============================================================================
  34. | Author       Date       Change 
  35. | sbyrne     16 May 90      Changed from being variableSubclass to
  36. |              variableWordSubclass.
  37. |
  38. | sbyrne     25 Apr 89      created.
  39. |
  40. "
  41.  
  42.  
  43. "*** Having this be variable seems wrong ***"
  44. Magnitude variableWordSubclass: #Character 
  45.       instanceVariableNames: ''
  46.       classVariableNames: ''
  47.       poolDictionaries: ''
  48.       category: nil.
  49.  
  50. Character comment: 
  51. 'My instances represent the 256 characters of the character set.  I provide
  52. messages to translate between integers and character objects, and provide
  53. names for some of the common unprintable characters.' !
  54.  
  55.  
  56. !Character class methodsFor: 'constants'!
  57.  
  58. backspace
  59.     "Returns the character 'backspace'"
  60.     ^Character value: 8
  61. !
  62.  
  63. tab
  64.     "Returns the character 'tab'"
  65.     ^Character value: 9
  66. !
  67.  
  68. nl
  69.     "Returns the character 'nl'"
  70.     ^Character value: 10
  71. !
  72.  
  73. newPage
  74.     "Returns the character 'newPage'"
  75.     ^Character value: 12
  76. !
  77.  
  78. cr
  79.     "Returns the character 'cr'"
  80.     ^Character value: 13
  81. !
  82.  
  83. esc
  84.     "Returns the character 'esc'"
  85.     ^Character value: 27
  86. !
  87.  
  88. space
  89.     "Returns the character 'space'"
  90.     ^Character value: 32    "could also return $ "
  91. !!
  92.  
  93.  
  94. !Character class methodsFor: 'Instance creation'!
  95.  
  96. digitValue: anInteger
  97.     "Returns a character that corresponds to anInteger.  0-9 map to $0-$9,
  98.     10-35 map to $A-$Z"
  99.     (anInteger between: 0 and: 9)
  100.         ifTrue: [ ^Character value: anInteger + 48 ]. "48 == $0"
  101.     (anInteger between: 10 and: 35)
  102.         ifTrue: [ ^Character value: anInteger - 10 + 65 ]. "65 = $A"
  103.     ^self error: 'value not in range 0 to 35'
  104. !!
  105.  
  106.  
  107.  
  108. !Character methodsFor: 'converting'!
  109.  
  110. digitValue
  111.     "Returns the value of self interpreted as a digit.  Here, 'digit' means
  112.     either 0-9, or uppercase A-Z, which maps to 10-35."
  113.     (self between: $0 and: $9) ifTrue: [ ^self asciiValue - 48 ].
  114.                 "48 is $0"
  115.     (self between: $A and: $Z) ifTrue: [ ^self asciiValue - 65 + 10 ].
  116.                 "65 is $A"
  117.     ^self error: 'Invalid digit character'
  118. !!
  119.  
  120.  
  121.  
  122. !Character methodsFor: 'comparing'!
  123.  
  124. < aCharacter
  125.     ^self asciiValue < aCharacter asciiValue
  126. !
  127.  
  128. <= aCharacter
  129.     ^self asciiValue <= aCharacter asciiValue
  130. !
  131.  
  132. > aCharacter
  133.     ^self asciiValue > aCharacter asciiValue
  134. !
  135.  
  136. >= aCharacter
  137.     ^self asciiValue >= aCharacter asciiValue
  138. !!
  139.  
  140.  
  141.  
  142. !Character methodsFor: 'testing'!
  143.  
  144. isDigit
  145.     "True if self is a 0-9 digit"
  146.     ^self between: $0 and: $9
  147. !
  148.  
  149. isLetter
  150.     "True if self is an upper- or lowercase letter"
  151.     ^(self between: $a and: $z) or: [ self between: $A and: $Z ]
  152. !
  153.  
  154. isAlphaNumeric
  155.     "True if self is a letter or a digit"
  156.     ^self isLetter or: [ self isDigit ]
  157. !
  158.  
  159. isLowercase
  160.     "True if self is a lowercase letter"
  161.     ^self between: $a and: $z
  162. !
  163.  
  164. isUppercase
  165.     "True if self is uppercase"
  166.     ^self between: $A and: $Z
  167. !
  168.  
  169. isSeparator
  170.     "Returns true if self is a space, cr, tab, nl, or newPage"
  171.     self > Character space ifTrue: [ ^false ].
  172.     self = Character space ifTrue: [ ^true ].
  173.     self = Character cr ifTrue: [ ^true ].
  174.     self = Character tab ifTrue: [ ^true ].
  175.     self = Character nl ifTrue: [ ^true ].
  176.     self = Character newPage ifTrue: [ ^true ].
  177.     ^false
  178. !
  179.  
  180. isVowel
  181.     "Returns true if self is a, e, i, o, or u; case insensitive"
  182.     | char |
  183.     char _ self asLowercase.
  184.     char = $a ifTrue: [ ^true ].    
  185.     char = $e ifTrue: [ ^true ].    
  186.     char = $i ifTrue: [ ^true ].    
  187.     char = $o ifTrue: [ ^true ].    
  188.     char = $u ifTrue: [ ^true ].    
  189.     ^false
  190. !!
  191.  
  192.  
  193.  
  194. !Character methodsFor: 'Coercion methods'!
  195.  
  196. asLowercase
  197.     "Returns self as a lowercase character if it's an uppercase letter,
  198.      otherwise returns the character unchanged."
  199.     self isUppercase ifFalse: [ ^self ].
  200.     ^Character value: (self asciiValue) + 32
  201. !
  202.  
  203. asUppercase
  204.     "Returns self as a uppercase character if it's an lowercase letter,
  205.      otherwise returns the character unchanged."
  206.     self isLowercase ifFalse: [ ^self ].
  207.     ^Character value: (self asciiValue) - 32
  208. !
  209.  
  210. asSymbol
  211.     "Returns the character self as a symbol."
  212.     ^Symbol internCharacter: self
  213. !!
  214.  
  215.  
  216.  
  217. !Character methodsFor: 'printing'!
  218.  
  219. printOn: aStream
  220.     aStream nextPut: self
  221. !!
  222.  
  223.  
  224.  
  225. !Character methodsFor: 'storing'!
  226.  
  227. storeOn: aStream
  228.     aStream nextPut: $$.
  229.     aStream nextPut: self
  230. !!
  231.  
  232.